1 files changed, 59 insertions, 0 deletions
diff --git a/kernel/arch/arm/vfp/entry.S b/kernel/arch/arm/vfp/entry.S
new file mode 100644
index 000000000..2e78760f3
--- /dev/null
+++ b/kernel/arch/arm/vfp/entry.S
@@ -0,0 +1,59 @@
+/*
+ *  linux/arch/arm/vfp/entry.S
+ *
+ *  Copyright (C) 2004 ARM Limited.
+ *  Written by Deep Blue Solutions Limited.
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License version 2 as
+ * published by the Free Software Foundation.
+ */
+#include <linux/init.h>
+#include <linux/linkage.h>
+#include <asm/thread_info.h>
+#include <asm/vfpmacros.h>
+#include <asm/assembler.h>
+#include <asm/asm-offsets.h>
+
+@ VFP entry point.
+@
+@  r0  = instruction opcode (32-bit ARM or two 16-bit Thumb)
+@  r2  = PC value to resume execution after successful emulation
+@  r9  = normal "successful" return address
+@  r10 = this threads thread_info structure
+@  lr  = unrecognised instruction return address
+@  IRQs enabled.
+@
+ENTRY(do_vfp)
+	inc_preempt_count r10, r4
+ 	ldr	r4, .LCvfp
+	ldr	r11, [r10, #TI_CPU]	@ CPU number
+	add	r10, r10, #TI_VFPSTATE	@ r10 = workspace
+	ldr	pc, [r4]		@ call VFP entry point
+ENDPROC(do_vfp)
+
+ENTRY(vfp_null_entry)
+	dec_preempt_count_ti r10, r4
+	ret	lr
+ENDPROC(vfp_null_entry)
+
+	.align	2
+.LCvfp:
+	.word	vfp_vector
+
+@ This code is called if the VFP does not exist. It needs to flag the
+@ failure to the VFP initialisation code.
+
+	__INIT
+ENTRY(vfp_testing_entry)
+	dec_preempt_count_ti r10, r4
+	ldr	r0, VFP_arch_address
+	str	r0, [r0]		@ set to non-zero value
+	ret	r9			@ we have handled the fault
+ENDPROC(vfp_testing_entry)
+
+	.align	2
+VFP_arch_address:
+	.word	VFP_arch
+
+	__FINIT