1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
|
# Copyright 2016 Red Hat, Inc.
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may
# not use this file except in compliance with the License. You may obtain
# a copy of the License at
#
# http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations
# under the License.
#
# == Class: tripleo::profile::pacemaker::glance
#
# Glance Pacemaker HA profile for tripleo
#
# === Parameters
#
# [*bootstrap_node*]
# (Optional) The hostname of the node responsible for bootstrapping tasks
# Defaults to hiera('bootstrap_nodeid')
#
# [*step*]
# (Optional) The current step in deployment. See tripleo-heat-templates
# for more details.
# Defaults to hiera('step')
#
# [*glance_backend*]
# (Optional) Glance backend(s) to use.
# Defaults to downcase(hiera('glance_backend', 'swift'))
#
# [*glance_file_pcmk_manage*]
# (Optional) Whether or not manage glance_file_pcmk.
# Defaults to hiera('glance_file_pcmk_manage', false)
#
# [*glance_file_pcmk_device*]
# (Optional) Device to mount glance file backend.
# Defaults to hiera('glance_file_pcmk_device', '')
#
# [*glance_file_pcmk_directory*]
# (Optional) Directory to mount glance file backend.
# Defaults to hiera('glance_file_pcmk_directory', '')
#
# [*glance_file_pcmk_fstype*]
# (Optional) Filesystem type to mount glance file backend.
# Defaults to hiera('glance_file_pcmk_fstype', '')
#
# [*glance_file_pcmk_options*]
# (Optional) pcmk options to mount Glance file backend..
# Defaults to hiera('glance_file_pcmk_options', '')
#
class tripleo::profile::pacemaker::glance (
$bootstrap_node = hiera('bootstrap_nodeid'),
$step = hiera('step'),
$glance_backend = downcase(hiera('glance_backend', 'swift')),
$glance_file_pcmk_manage = hiera('glance_file_pcmk_manage', false),
$glance_file_pcmk_device = hiera('glance_file_pcmk_device', ''),
$glance_file_pcmk_directory = hiera('glance_file_pcmk_directory', ''),
$glance_file_pcmk_fstype = hiera('glance_file_pcmk_fstype', ''),
$glance_file_pcmk_options = hiera('glance_file_pcmk_options', ''),
) {
if $::hostname == downcase($bootstrap_node) {
$pacemaker_master = true
} else {
$pacemaker_master = false
}
if $step >= 4 {
class { '::tripleo::profile::base::glance::api':
manage_service => false,
enabled => false,
}
class { '::tripleo::profile::base::glance::registry':
sync_db => $pacemaker_master,
manage_service => false,
enabled => false,
}
if $glance_backend == 'file' and $glance_file_pcmk_manage {
$secontext = 'context="system_u:object_r:glance_var_lib_t:s0"'
pacemaker::resource::filesystem { 'glance-fs':
device => $glance_file_pcmk_device,
directory => $glance_file_pcmk_directory,
fstype => $glance_file_pcmk_fstype,
fsoptions => join([$secontext, $glance_file_pcmk_options],','),
clone_params => '',
}
}
}
if $step >= 5 and $pacemaker_master {
pacemaker::resource::service { $::glance::params::registry_service_name :
clone_params => 'interleave=true',
require => Pacemaker::Resource::Ocf['openstack-core'],
}
pacemaker::resource::service { $::glance::params::api_service_name :
clone_params => 'interleave=true',
}
pacemaker::constraint::base { 'keystone-then-glance-registry-constraint':
constraint_type => 'order',
first_resource => 'openstack-core-clone',
second_resource => "${::glance::params::registry_service_name}-clone",
first_action => 'start',
second_action => 'start',
require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
Pacemaker::Resource::Ocf['openstack-core']],
}
pacemaker::constraint::base { 'glance-registry-then-glance-api-constraint':
constraint_type => 'order',
first_resource => "${::glance::params::registry_service_name}-clone",
second_resource => "${::glance::params::api_service_name}-clone",
first_action => 'start',
second_action => 'start',
require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
Pacemaker::Resource::Service[$::glance::params::api_service_name]],
}
pacemaker::constraint::colocation { 'glance-api-with-glance-registry-colocation':
source => "${::glance::params::api_service_name}-clone",
target => "${::glance::params::registry_service_name}-clone",
score => 'INFINITY',
require => [Pacemaker::Resource::Service[$::glance::params::registry_service_name],
Pacemaker::Resource::Service[$::glance::params::api_service_name]],
}
}
}
|
