MidoNet services manifests

Provide TripleO overcloud manifests to deploy MidoNet and the cluster
services that needs to run.

Change-Id: I24f852e74fc4652d4609e1a71897e813448055fe

4 files changed, 312 insertions, 0 deletions

diff --git a/manifests/cluster/cassandra.pp b/manifests/cluster/cassandra.pp
new file mode 100644
index 0000000..a810ccd
--- /dev/null
+++ b/manifests/cluster/cassandra.pp
@@ -0,0 +1,69 @@
+#
+# Copyright (C) 2015 Midokura SARL
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::cluster::cassandra
+#
+# Deploys a cassandra service that belongs to a cluster. Uses puppet-cassandra
+#
+# == Parameters:
+#
+# [*cassandra_servers*]
+#  (required) All the IP addresses of the cassandra cluster.
+#  Array of strings value.
+#
+# [*cassandra_ip*]
+#  (required) IP address of the current host.
+#  String value
+#
+# [*storage_port*]
+#  (optional) Inter-node cluster communication port.
+#  Defaults to 7000.
+#
+# [*ssl_storage_port*]
+#  (optional) SSL Inter-node cluster communication port.
+#  Defaults to 7001.
+#
+# [*client_port*]
+#  (optional) Cassandra client port.
+#  Defaults to 9042.
+#
+# [*client_port_thrift*]
+#  (optional) Cassandra client port thrift.
+#  Defaults to 9160.
+#
+class tripleo::cluster::cassandra(
+  $cassandra_servers,
+  $cassandra_ip,
+  $storage_port       = '7000',
+  $ssl_storage_port   = '7001',
+  $client_port        = '9042',
+  $client_port_thrift = '9160'
+)
+{
+  validate_array($cassandra_servers)
+  validate_ipv4_address($cassandra_ip)
+
+  class {'::cassandra::run':
+    seeds              => $cassandra_servers,
+    seed_address       => $cassandra_ip,
+    conf_dir           => '/etc/cassandra/default.conf',
+    pid_dir            => '/var/run/cassandra',
+    service_path       => '/sbin',
+    storage_port       => $storage_port,
+    ssl_storage_port   => $ssl_storage_port,
+    client_port        => $client_port,
+    client_port_thrift => $client_port_thrift
+  }
+}
diff --git a/manifests/cluster/zookeeper.pp b/manifests/cluster/zookeeper.pp
new file mode 100644
index 0000000..6f4adbc
--- /dev/null
+++ b/manifests/cluster/zookeeper.pp
@@ -0,0 +1,65 @@
+#
+# Copyright (C) 2015 Midokura SARL
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::cluster::zookeeper
+#
+# Deploys a zookeeper service that belongs to a cluster. Uses deric-zookeeper
+#
+# == Parameters:
+#
+# [*zookeeper_server_ips*]
+#  (required) List of IP addresses of the zookeeper cluster.
+#  Arrays of strings value.
+#
+# [*zookeeper_client_ip*]
+#  (required) IP address of the host where zookeeper will listen IP addresses.
+#  String (IPv4) value.
+#
+# [*zookeeper_hostnames*]
+#  (required) List of hostnames of the zookeeper cluster. The hostname of the
+#  node will be used to define the ID of the zookeeper configuration
+#  Array of strings value.
+#
+
+class tripleo::cluster::zookeeper(
+  $zookeeper_server_ips,
+  $zookeeper_client_ip,
+  $zookeeper_hostnames
+)
+{
+  validate_array($zookeeper_server_ips)
+  validate_ipv4_address($zookeeper_client_ip)
+  validate_array($zookeeper_hostnames)
+
+  # TODO(devvesa) Zookeeper package should provide these paths,
+  # remove this lines as soon as it will.
+  file {['/usr/lib', '/usr/lib/zookeeper', '/usr/lib/zookeeper/bin/']:
+    ensure => directory
+  }
+
+  file {'/usr/lib/zookeeper/bin/zkEnv.sh':
+    ensure => link,
+    target => '/usr/libexec/zkEnv.sh'
+  }
+
+  class {'::zookeeper':
+    servers   => $zookeeper_server_ips,
+    client_ip => $zookeeper_client_ip,
+    id        => extract_id($zookeeper_hostnames, $::hostname),
+    cfg_dir   => '/etc/zookeeper/conf',
+  }
+
+  File['/usr/lib/zookeeper/bin/zkEnv.sh'] -> Class['::zookeeper']
+}
diff --git a/manifests/network/midonet/agent.pp b/manifests/network/midonet/agent.pp
new file mode 100644
index 0000000..2f1da94
--- /dev/null
+++ b/manifests/network/midonet/agent.pp
@@ -0,0 +1,61 @@
+#
+# Copyright (C) 2015 Midokura SARL
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::network::midonet::agent
+#
+# Configure the midonet agent
+#
+# == Parameters:
+#
+# [*zookeeper_servers*]
+#  (required) List of IPs of the zookeeper server cluster. It will configure
+#  the connection using the 2181 port.
+#  Array of strings value.
+#
+# [*cassandra_seeds*]
+#  (required) List of IPs of the cassandra cluster.
+#  Array of strings value.
+#
+class tripleo::network::midonet::agent (
+  $zookeeper_servers,
+  $cassandra_seeds
+) {
+
+  validate_array($zookeeper_servers)
+  validate_array($cassandra_seeds)
+
+  # FIXME: This statement should be controlled by hiera on heat templates
+  # project
+  # Make sure openvswitch service is not running
+  service {'openvswitch':
+    ensure => stopped,
+    enable => false
+  }
+
+  exec {'delete datapaths':
+    command => '/usr/bin/mm-dpctl --delete-dp ovs-system',
+    path    => '/usr/bin:/usr/sbin:/bin',
+    onlyif  => '/usr/bin/mm-dpctl --show-dp ovs-system'
+  }
+
+  # Configure and run the agent
+  class {'::midonet::midonet_agent':
+    zk_servers      => list_to_zookeeper_hash($zookeeper_servers),
+    cassandra_seeds => $cassandra_seeds
+  }
+
+  Service['openvswitch'] -> Class['::midonet::midonet_agent::run']
+  Exec['delete datapaths'] -> Class['::midonet::midonet_agent::run']
+}
diff --git a/manifests/network/midonet/api.pp b/manifests/network/midonet/api.pp
new file mode 100644
index 0000000..33b2217
--- /dev/null
+++ b/manifests/network/midonet/api.pp
@@ -0,0 +1,117 @@
+#
+# Copyright (C) 2015 Midokura SARL
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::network::midonet::api
+#
+# Configure the MidoNet API
+#
+# == Parameters:
+#
+# [*zookeeper_servers*]
+#  (required) List IPs of the zookeeper server cluster. Zookeeper is the
+#  backend database where MidoNet stores the virtual network topology.
+#  Array of strings value.
+#
+# [*vip*]
+#  (required) Public Virtual IP where the API will be exposed.
+#  String (IPv4) value.
+#
+# [*keystone_ip*]
+#  (required) MidoNet API is registered as an OpenStack service. Provide the
+#  keystone ip address.
+#  String (IPv4) value.
+#
+# [*keystone_admin_token*]
+#  (required) MidoNet API is registered as an OpenStack service. It needs the
+#  keystone admin token to perform some admin calls.
+#  String value.
+#
+# [*bind_address*]
+#  (required) MidoNet API uses a Tomcat instance to offer the REST service. The
+#  ip address where to bind the tomcat service.
+#  String (IPv4) value.
+#
+# [*admin_password*]
+#  (required) OpenStack admin user password.
+#  String value.
+#
+# [*keystone_port*]
+#  (optional) MidoNet API is registered as an OpenStack service. Provide
+#  the keystone port.
+#  Defaults to 35357
+#
+# [*keystone_tenant_name*]
+#  (optional) Tenant of the keystone service.
+#  Defaults to 'admin'
+#
+# [*admin_user_name*]
+#  (optional) OpenStack admin user name.
+#  Defaults to 'admin'
+#
+# [*admin_tenant_name*]
+#  (optional). OpenStack admin tenant name.
+#  Defaults to 'admin'
+#
+
+class tripleo::network::midonet::api(
+  $zookeeper_servers,
+  $vip,
+  $keystone_ip,
+  $keystone_admin_token,
+  $bind_address,
+  $admin_password,
+  $keystone_port         = 35357,
+  $keystone_tenant_name  = 'admin',
+  $admin_user_name       = 'admin',
+  $admin_tenant_name     = 'admin'
+)
+{
+  validate_array($zookeeper_servers)
+  validate_ip_address($vip)
+  validate_ip_address($keystone_ip)
+  validate_ip_address($bind_address)
+
+  # Run Tomcat and MidoNet API
+  class {'::tomcat':
+    install_from_source => false
+  } ->
+
+  package {'midonet-api':
+    ensure => present
+  } ->
+
+  class {'::midonet::midonet_api::run':
+    zk_servers           => list_to_zookeeper_hash($zookeeper_servers),
+    keystone_auth        => true,
+    tomcat_package       => 'tomcat',
+    vtep                 => false,
+    api_ip               => $vip,
+    api_port             => '8081',
+    keystone_host        => $keystone_ip,
+    keystone_port        => $keystone_port,
+    keystone_admin_token => $keystone_admin_token,
+    keystone_tenant_name => $keystone_tenant_name,
+    catalina_base        => '/usr/share/tomcat',
+    bind_address         => $bind_address
+  }
+
+  # Configure the CLI
+  class {'::midonet::midonet_cli':
+    api_endpoint => "http://${vip}:8081/midonet-api",
+    username     => $admin_user_name,
+    password     => $admin_password,
+    tenant_name  => $admin_tenant_name
+  }
+}