Add neutron profiles

Implements: blueprint refactor-puppet-manifests

Add neutron profiles for both pacemaker and non-ha.

HA profiles are designed such that they include the base
profiles, disabling features as needed, while the base
profile can be used independently.

Co-Authored-By: Dan Prince <dprince@redhat.com>

Change-Id: Ida781badbcd63bbcb481a2170638aefe262b717b

8 files changed, 580 insertions, 0 deletions

diff --git a/manifests/profile/pacemaker/neutron.pp b/manifests/profile/pacemaker/neutron.pp
new file mode 100644
index 0000000..03ccbc3
--- /dev/null
+++ b/manifests/profile/pacemaker/neutron.pp
@@ -0,0 +1,184 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::neutron
+#
+# Neutron server profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The step in the deployment
+#   Defaults to hiera('step')
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the pacemaker master
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*enable_l3*]
+#   (Optional) Whether to include the Neutron L3 agent pacemaker profile
+#   Defaults to hiera('neutron::enable_l3_agent', false)
+#
+# [*enable_dhcp*]
+#   (Optional) Whether to include the Neutron DHCP agent pacemaker profile
+#   Defaults to hiera('neutron::enable_dhcp_agent', false)
+#
+# [*enable_metadata*]
+#   (Optional) Whether to include the Neutron Metadata agent pacemaker profile
+#   Defaults to hiera('neutron::enable_metadata_agent', false)
+#
+# [*enable_ovs*]
+#   (Optional) Whether to include the Neutron OVS agent pacemaker profile
+#   Defaults to hiera('neutron::enable_ovs_agent', false)
+#
+class tripleo::profile::pacemaker::neutron (
+  $step             = hiera('step'),
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+  # We can drop the hiera defaults once the neutron roles are decomposed
+  $enable_l3        = hiera('neutron::enable_l3_agent', false),
+  $enable_dhcp      = hiera('neutron::enable_dhcp_agent', false),
+  $enable_metadata  = hiera('neutron::enable_metadata_agent', false),
+  $enable_ovs       = hiera('neutron::enable_ovs_agent', false),
+) {
+
+  Service <|
+    tag == 'neutron-service'
+  |> {
+    hasrestart => true,
+    restart    => '/bin/true',
+    start      => '/bin/true',
+    stop       => '/bin/true',
+  }
+
+  if $step >= 4 {
+    include ::neutron::params
+    include ::tripleo::profile::base::neutron
+
+    # To be removed when puppet-oslo comes into service
+    neutron_config {
+      'DEFAULT/notification_driver': value => 'messaging';
+    }
+  }
+
+  if $step >= 5 and $pacemaker_master == downcase($::hostname) {
+    if $step == 5 {
+      # Neutron
+      # NOTE(gfidente): Neutron will try to populate the database with some data
+      # as soon as neutron-server is started; to avoid races we want to make this
+      # happen only on one node, before normal Pacemaker initialization
+      # https://bugzilla.redhat.com/show_bug.cgi?id=1233061
+      # NOTE(emilien): we need to run this Exec only at Step 4 otherwise this exec
+      # will try to start the service while it's already started by Pacemaker
+      # It would result to a deployment failure since systemd would return 1 to Puppet
+      # and the overcloud would fail to deploy (6 would be returned).
+      # This conditional prevents from a race condition during the deployment.
+      # https://bugzilla.redhat.com/show_bug.cgi?id=1290582
+      exec { 'neutron-server-systemd-start-sleep' :
+        command => 'systemctl start neutron-server && /usr/bin/sleep 5',
+        path    => '/usr/bin',
+        unless  => '/sbin/pcs resource show neutron-server',
+      } ->
+      pacemaker::resource::service { $::neutron::params::server_service:
+        clone_params => 'interleave=true',
+        require      => Pacemaker::Resource::Ocf['openstack-core']
+      }
+    } else {
+      pacemaker::resource::service { $::neutron::params::server_service:
+        clone_params => 'interleave=true',
+        require      => Pacemaker::Resource::Ocf['openstack-core']
+      }
+    }
+
+    pacemaker::constraint::base { 'keystone-to-neutron-server-constraint':
+      constraint_type => 'order',
+      first_resource  => 'openstack-core-clone',
+      second_resource => "${::neutron::params::server_service}-clone",
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Ocf['openstack-core'],
+                          Pacemaker::Resource::Service[$::neutron::params::server_service]],
+    }
+
+    if $enable_ovs {
+      pacemaker::constraint::base { 'neutron-openvswitch-agent-to-dhcp-agent-constraint':
+        constraint_type => 'order',
+        first_resource  => "${::neutron::params::ovs_agent_service}-clone",
+        second_resource => "${::neutron::params::dhcp_agent_service}-clone",
+        first_action    => 'start',
+        second_action   => 'start',
+        require         => [Pacemaker::Resource::Service[$::neutron::params::ovs_agent_service],
+                            Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service]],
+      }
+    }
+
+    if $enable_dhcp and $enable_ovs {
+      pacemaker::constraint::base { 'neutron-server-to-openvswitch-agent-constraint':
+        constraint_type => 'order',
+        first_resource  => "${::neutron::params::server_service}-clone",
+        second_resource => "${::neutron::params::ovs_agent_service}-clone",
+        first_action    => 'start',
+        second_action   => 'start',
+        require         => [Pacemaker::Resource::Service[$::neutron::params::server_service],
+                            Pacemaker::Resource::Service[$::neutron::params::ovs_agent_service]],
+      }
+
+      pacemaker::constraint::colocation { 'neutron-openvswitch-agent-to-dhcp-agent-colocation':
+        source  => "${::neutron::params::dhcp_agent_service}-clone",
+        target  => "${::neutron::params::ovs_agent_service}-clone",
+        score   => 'INFINITY',
+        require => [Pacemaker::Resource::Service[$::neutron::params::ovs_agent_service],
+                    Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service]],
+      }
+    }
+
+    if $enable_dhcp and $enable_l3 {
+      pacemaker::constraint::base { 'neutron-dhcp-agent-to-l3-agent-constraint':
+        constraint_type => 'order',
+        first_resource  => "${::neutron::params::dhcp_agent_service}-clone",
+        second_resource => "${::neutron::params::l3_agent_service}-clone",
+        first_action    => 'start',
+        second_action   => 'start',
+        require         => [Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service],
+                            Pacemaker::Resource::Service[$::neutron::params::l3_agent_service]]
+      }
+
+      pacemaker::constraint::colocation { 'neutron-dhcp-agent-to-l3-agent-colocation':
+        source  => "${::neutron::params::l3_agent_service}-clone",
+        target  => "${::neutron::params::dhcp_agent_service}-clone",
+        score   => 'INFINITY',
+        require => [Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service],
+                    Pacemaker::Resource::Service[$::neutron::params::l3_agent_service]]
+      }
+    }
+
+    if $enable_l3 and $enable_metadata {
+      pacemaker::constraint::base { 'neutron-l3-agent-to-metadata-agent-constraint':
+        constraint_type => 'order',
+        first_resource  => "${::neutron::params::l3_agent_service}-clone",
+        second_resource => "${::neutron::params::metadata_agent_service}-clone",
+        first_action    => 'start',
+        second_action   => 'start',
+        require         => [Pacemaker::Resource::Service[$::neutron::params::l3_agent_service],
+                            Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service]]
+      }
+      pacemaker::constraint::colocation { 'neutron-l3-agent-to-metadata-agent-colocation':
+        source  => "${::neutron::params::metadata_agent_service}-clone",
+        target  => "${::neutron::params::l3_agent_service}-clone",
+        score   => 'INFINITY',
+        require => [Pacemaker::Resource::Service[$::neutron::params::l3_agent_service],
+                    Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service]]
+      }
+    }
+  }
+}
diff --git a/manifests/profile/pacemaker/neutron/dhcp.pp b/manifests/profile/pacemaker/neutron/dhcp.pp
new file mode 100644
index 0000000..841d225
--- /dev/null
+++ b/manifests/profile/pacemaker/neutron/dhcp.pp
@@ -0,0 +1,47 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::neutron::dhcp
+#
+# Neutron DHCP Agent server profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the pacemaker master
+#   Defaults to hiera('bootstrap_nodeid')
+#
+class tripleo::profile::pacemaker::neutron::dhcp (
+  $step             = hiera('step'),
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+) {
+
+  include ::neutron::params
+  include ::tripleo::profile::pacemaker::neutron
+
+  class { '::tripleo::profile::base::neutron::dhcp':
+    manage_service => false,
+    enabled        => false,
+  }
+  if $step >= 5 and downcase($::hostname) == $pacemaker_master {
+    pacemaker::resource::service { $::neutron::params::dhcp_agent_service:
+      clone_params => 'interleave=true',
+    }
+  }
+}
diff --git a/manifests/profile/pacemaker/neutron/l3.pp b/manifests/profile/pacemaker/neutron/l3.pp
new file mode 100644
index 0000000..a900016
--- /dev/null
+++ b/manifests/profile/pacemaker/neutron/l3.pp
@@ -0,0 +1,47 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::neutron::l3
+#
+# Neutron L3 Agent server profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the pacemaker master
+#   Defaults to hiera('bootstrap_nodeid')
+#
+class tripleo::profile::pacemaker::neutron::l3 (
+  $step             = hiera('step'),
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+) {
+
+  include ::neutron::params
+  include ::tripleo::profile::pacemaker::neutron
+
+  class { '::tripleo::profile::base::neutron::l3':
+    manage_service => false,
+    enabled        => false,
+  }
+  if $step >= 5 and downcase($::hostname) == $pacemaker_master {
+    pacemaker::resource::service { $::neutron::params::l3_agent_service:
+      clone_params => 'interleave=true',
+    }
+  }
+}
diff --git a/manifests/profile/pacemaker/neutron/metadata.pp b/manifests/profile/pacemaker/neutron/metadata.pp
new file mode 100644
index 0000000..4030bb2
--- /dev/null
+++ b/manifests/profile/pacemaker/neutron/metadata.pp
@@ -0,0 +1,47 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::neutron::metadata
+#
+# Neutron Metadata Agent server profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the pacemaker master
+#   Defaults to hiera('bootstrap_nodeid')
+#
+class tripleo::profile::pacemaker::neutron::metadata (
+  $step             = hiera('step'),
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+) {
+
+  include ::neutron::params
+  include ::tripleo::profile::pacemaker::neutron
+
+  class { '::tripleo::profile::base::neutron::metadata':
+    manage_service => false,
+    enabled        => false,
+  }
+  if $step >= 5 and downcase($::hostname) == $pacemaker_master {
+    pacemaker::resource::service { $::neutron::params::metadata_agent_service:
+      clone_params => 'interleave=true',
+    }
+  }
+}
diff --git a/manifests/profile/pacemaker/neutron/midonet.pp b/manifests/profile/pacemaker/neutron/midonet.pp
new file mode 100644
index 0000000..a4ec831
--- /dev/null
+++ b/manifests/profile/pacemaker/neutron/midonet.pp
@@ -0,0 +1,80 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::neutron::midonet
+#
+# Neutron Midonet driver Pacemaker HA profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the pacemaker master
+#   Defaults to hiera('bootstrap_nodeid')
+#
+class tripleo::profile::pacemaker::neutron::midonet (
+  $step             = hiera('step'),
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+) {
+  include ::neutron::params
+  include ::tripleo::profile::pacemaker::neutron
+  include ::tripleo::profile::base::neutron::midonet
+
+  if $step >= 5 and downcase($::hostname) == $pacemaker_master {
+
+    pacemaker::resource::service {'tomcat':
+      clone_params => 'interleave=true',
+    }
+
+    #midonet-chain chain keystone-->neutron-server-->dhcp-->metadata->tomcat
+    pacemaker::constraint::base { 'neutron-server-to-dhcp-agent-constraint':
+      constraint_type => 'order',
+      first_resource  => "${::neutron::params::server_service}-clone",
+      second_resource => "${::neutron::params::dhcp_agent_service}-clone",
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Service[$::neutron::params::server_service],
+                          Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service]],
+    }
+    pacemaker::constraint::base { 'neutron-dhcp-agent-to-metadata-agent-constraint':
+      constraint_type => 'order',
+      first_resource  => "${::neutron::params::dhcp_agent_service}-clone",
+      second_resource => "${::neutron::params::metadata_agent_service}-clone",
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service],
+                          Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service]],
+    }
+    pacemaker::constraint::base { 'neutron-metadata-agent-to-tomcat-constraint':
+      constraint_type => 'order',
+      first_resource  => "${::neutron::params::metadata_agent_service}-clone",
+      second_resource => 'tomcat-clone',
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service],
+                          Pacemaker::Resource::Service['tomcat']],
+    }
+    pacemaker::constraint::colocation { 'neutron-dhcp-agent-to-metadata-agent-colocation':
+      source  => "${::neutron::params::metadata_agent_service}-clone",
+      target  => "${::neutron::params::dhcp_agent_service}-clone",
+      score   => 'INFINITY',
+      require => [Pacemaker::Resource::Service[$::neutron::params::dhcp_agent_service],
+                  Pacemaker::Resource::Service[$::neutron::params::metadata_agent_service]],
+    }
+  }
+}
diff --git a/manifests/profile/pacemaker/neutron/ml2.pp b/manifests/profile/pacemaker/neutron/ml2.pp
new file mode 100644
index 0000000..6c6e580
--- /dev/null
+++ b/manifests/profile/pacemaker/neutron/ml2.pp
@@ -0,0 +1,25 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::neutron::ml2
+#
+# Neutron ML2 driver Pacemaker HA profile for tripleo
+#
+# === Parameters
+#
+class tripleo::profile::pacemaker::neutron::ml2 {
+  include ::neutron::params
+  include ::tripleo::profile::pacemaker::neutron
+  include ::tripleo::profile::base::neutron::ml2
+}
diff --git a/manifests/profile/pacemaker/neutron/ovs.pp b/manifests/profile/pacemaker/neutron/ovs.pp
new file mode 100644
index 0000000..c3ce36e
--- /dev/null
+++ b/manifests/profile/pacemaker/neutron/ovs.pp
@@ -0,0 +1,92 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::neutron::ovs
+#
+# Neutron OVS Agent Pacemaker HA profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the pacemaker master
+#   Defaults to hiera('bootstrap_nodeid')
+#
+class tripleo::profile::pacemaker::neutron::ovs (
+  $step             = hiera('step'),
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+) {
+
+  include ::neutron::params
+  include ::tripleo::profile::pacemaker::neutron
+
+  class { '::tripleo::profile::base::neutron::ovs':
+    manage_service => false,
+    enabled        => false,
+  }
+
+  if $step >= 5 and downcase($::hostname) == $pacemaker_master {
+
+    pacemaker::resource::service { $::neutron::params::ovs_agent_service:
+      clone_params => 'interleave=true',
+    }
+
+    pacemaker::resource::ocf { $::neutron::params::ovs_cleanup_service:
+      ocf_agent_name => 'neutron:OVSCleanup',
+      clone_params   => 'interleave=true',
+    }
+    pacemaker::resource::ocf { 'neutron-netns-cleanup':
+      ocf_agent_name => 'neutron:NetnsCleanup',
+      clone_params   => 'interleave=true',
+    }
+
+    # neutron - one chain ovs-cleanup-->netns-cleanup-->ovs-agent
+    pacemaker::constraint::base { 'neutron-ovs-cleanup-to-netns-cleanup-constraint':
+      constraint_type => 'order',
+      first_resource  => "${::neutron::params::ovs_cleanup_service}-clone",
+      second_resource => 'neutron-netns-cleanup-clone',
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Ocf[$::neutron::params::ovs_cleanup_service],
+                          Pacemaker::Resource::Ocf['neutron-netns-cleanup']],
+    }
+    pacemaker::constraint::colocation { 'neutron-ovs-cleanup-to-netns-cleanup-colocation':
+      source  => 'neutron-netns-cleanup-clone',
+      target  => "${::neutron::params::ovs_cleanup_service}-clone",
+      score   => 'INFINITY',
+      require => [Pacemaker::Resource::Ocf[$::neutron::params::ovs_cleanup_service],
+                  Pacemaker::Resource::Ocf['neutron-netns-cleanup']],
+    }
+    pacemaker::constraint::base { 'neutron-netns-cleanup-to-openvswitch-agent-constraint':
+      constraint_type => 'order',
+      first_resource  => 'neutron-netns-cleanup-clone',
+      second_resource => "${::neutron::params::ovs_agent_service}-clone",
+      first_action    => 'start',
+      second_action   => 'start',
+      require         => [Pacemaker::Resource::Ocf['neutron-netns-cleanup'],
+                          Pacemaker::Resource::Service[$::neutron::params::ovs_agent_service]],
+    }
+    pacemaker::constraint::colocation { 'neutron-netns-cleanup-to-openvswitch-agent-colocation':
+      source  => "${::neutron::params::ovs_agent_service}-clone",
+      target  => 'neutron-netns-cleanup-clone',
+      score   => 'INFINITY',
+      require => [Pacemaker::Resource::Ocf['neutron-netns-cleanup'],
+                  Pacemaker::Resource::Service[$::neutron::params::ovs_agent_service]],
+    }
+  }
+}
diff --git a/manifests/profile/pacemaker/neutron/server.pp b/manifests/profile/pacemaker/neutron/server.pp
new file mode 100644
index 0000000..4ff2e88
--- /dev/null
+++ b/manifests/profile/pacemaker/neutron/server.pp
@@ -0,0 +1,58 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::neutron::server
+#
+# Neutron Server Pacemaker profile for tripleo
+#
+# === Parameters
+#
+# [*pacemaker_master*]
+#   (Optional) The hostname of the pacemaker master
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::pacemaker::neutron::server (
+  $pacemaker_master = hiera('bootstrap_nodeid'),
+  $step = hiera('step'),
+) {
+  include ::neutron::params
+  include ::tripleo::profile::pacemaker::neutron
+
+  if $step >= 5 {
+
+    class { '::tripleo::profile::base::neutron::server':
+      sync_db        => ($::hostname == downcase($pacemaker_master)),
+      manage_service => false,
+      enabled        => false,
+    }
+
+    if ($::hostname == downcase($pacemaker_master)) {
+      pacemaker::constraint::base { 'keystone-to-neutron-server-constraint':
+        constraint_type => 'order',
+        first_resource  => 'openstack-core-clone',
+        second_resource => "${::neutron::params::server_service}-clone",
+        first_action    => 'start',
+        second_action   => 'start',
+        require         => [Pacemaker::Resource::Ocf['openstack-core'],
+                            Pacemaker::Resource::Service[$::neutron::params::server_service]],
+      }
+    }
+
+  }
+}