Add neutron profiles

Implements: blueprint refactor-puppet-manifests

Add neutron profiles for both pacemaker and non-ha.

HA profiles are designed such that they include the base
profiles, disabling features as needed, while the base
profile can be used independently.

Co-Authored-By: Dan Prince <dprince@redhat.com>

Change-Id: Ida781badbcd63bbcb481a2170638aefe262b717b

10 files changed, 568 insertions, 0 deletions

diff --git a/manifests/profile/base/neutron.pp b/manifests/profile/base/neutron.pp
new file mode 100644
index 0000000..2958170
--- /dev/null
+++ b/manifests/profile/base/neutron.pp
@@ -0,0 +1,32 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron
+#
+# Neutron server profile for tripleo
+#
+# === Parameters
+#
+# [*step*]
+#   (Optional) The current step of the deployment
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron (
+  $step = hiera('step'),
+) {
+  if $step >= 4 {
+    include ::neutron
+    include ::neutron::config
+  }
+}
diff --git a/manifests/profile/base/neutron/dhcp.pp b/manifests/profile/base/neutron/dhcp.pp
new file mode 100644
index 0000000..1d7cc10
--- /dev/null
+++ b/manifests/profile/base/neutron/dhcp.pp
@@ -0,0 +1,53 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron::dhcp
+#
+# Neutron DHCP Agent profile for tripleo
+#
+# === Parameters
+#
+# [*neutron_dnsmasq_options*]
+#   (Optional)
+#   Defaults to hiera('neutron_dnsmasq_options')
+#
+# [*enabled*]
+#   (Optional) Whether to enable the Neutron DHCP Agent service
+#   Defaults to undef
+#
+# [*manage_service*]
+#   (Optional) Whether to manage the Neutron DHCP Agent service
+#   Defaults to undef
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron::dhcp (
+  $neutron_dnsmasq_options = hiera('neutron_dnsmasq_options', ''),
+  $enabled                 = undef,
+  $manage_service          = undef,
+  $step                    = hiera('step'),
+) {
+  if $step >= 4 {
+    include ::tripleo::profile::base::neutron
+    class { '::neutron::agents::dhcp':
+      manage_service => $manage_service,
+      enabled        => $enabled
+    }
+
+    Service<| title == 'neutron-server' |> -> Service <| title == 'neutron-dhcp' |>
+  }
+}
diff --git a/manifests/profile/base/neutron/l3.pp b/manifests/profile/base/neutron/l3.pp
new file mode 100644
index 0000000..f96833a
--- /dev/null
+++ b/manifests/profile/base/neutron/l3.pp
@@ -0,0 +1,52 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron::l3
+#
+# Neutron L3 Agent server profile for tripleo
+#
+# === Parameters
+#
+# [*neutron_ovs_use_veth*]
+#   (Optional) Whether to set ovs_use_veth (for older kernel support)
+#   Defaults to hiera('neutron_ovs_use_veth', false)
+#
+# [*enabled*]
+#   (Optional) Whether to enable the Neutron L3 Agent service
+#   Defaults to undef
+#
+# [*manage_service*]
+#   (Optional) Whether to manage the Neutron L3 Agent service
+#   Defaults to undef
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron::l3 (
+  $enabled        = undef,
+  $manage_service = undef,
+  $step           = hiera('step'),
+) {
+  if $step >= 4 {
+    include ::tripleo::profile::base::neutron
+    class { '::neutron::agents::l3':
+      manage_service => $manage_service,
+      enabled        => $enabled
+    }
+
+    Service<| title == 'neutron-server' |> -> Service <| title == 'neutron-l3' |>
+  }
+}
diff --git a/manifests/profile/base/neutron/metadata.pp b/manifests/profile/base/neutron/metadata.pp
new file mode 100644
index 0000000..bdad751
--- /dev/null
+++ b/manifests/profile/base/neutron/metadata.pp
@@ -0,0 +1,48 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron::metadata
+#
+# Neutron Metadata Agent profile for tripleo
+#
+# === Parameters
+#
+# [*enabled*]
+#   (Optional) Whether to enable the Neutron Metadata Agent service
+#   Defaults to undef
+#
+# [*manage_service*]
+#   (Optional) Whether to manage the Neutron Metadata Agent service
+#   Defaults to undef
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron::metadata (
+  $enabled        = undef,
+  $manage_service = undef,
+  $step           = hiera('step'),
+) {
+  if $step >= 4 {
+    include ::tripleo::profile::base::neutron
+    class { '::neutron::agents::metadata':
+      manage_service => $manage_service,
+      enabled        => $enabled
+    }
+
+    Service<| title == 'neutron-server' |> -> Service<| title == 'neutron-metadata' |>
+  }
+}
diff --git a/manifests/profile/base/neutron/midonet.pp b/manifests/profile/base/neutron/midonet.pp
new file mode 100644
index 0000000..7374c57
--- /dev/null
+++ b/manifests/profile/base/neutron/midonet.pp
@@ -0,0 +1,129 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron::midonet
+#
+# Midonet Neutron profile for tripleo
+#
+# === Parameters
+#
+# [*vip*]
+#   (Optional) Public Virtual IP Address for this cloud
+#   Defaults to hiera('tripleo::loadbalancer::public_virtual_ip')
+#
+# [*keystone_admin_token*]
+#   (Optional) The Keystone Admin Token
+#   Defaults to hiera('keystone::admin_token')
+#
+# [*zookeeper_client_ip*]
+#   (Optional) The IP of the Zookeeper Client
+#   Defaults to hiera('neutron::bind_host')
+#
+# [*zookeeper_hostnames*]
+#   (Optional) The IPs of the Zookeeper Servers
+#   Defaults to hiera('controller_node_names')
+#
+# [*neutron_api_node_ips*]
+#   (Optional) The IPs of the Neutron API hosts
+#   Defaults to hiera('neutron_api_node_ips')
+#
+# [*bind_address*]
+#   (Optional) The address to bind Cassandra and Midonet API to
+#   Defaults to hiera('neutron::bind_host')
+#
+# [*admin_password*]
+#   (Optional) Admin Password for Midonet API
+#   Defaults to hiera('admin_password')
+#
+# [*zk_on_controller*]
+#   (Optional) Whether to put zookeeper on the controllers
+#   Defaults to hiera('enable_zookeeper_on_controller')
+#
+# [*neutron_auth_tenant*]
+#   (Optional) Tenant to use for Neutron authentication
+#   Defaults to hiera('neutron::server::auth_tenant')
+#
+# [*neutron_auth_password*]
+#   (Optional) Password to use for Neutron authentication
+#   Defaults to hiera('neutron::server::auth_password')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+# [*step*]
+#   (Optional) The current step of the deployment
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron::midonet (
+  $vip                   = hiera('tripleo::loadbalancer::public_virtual_ip', ''),
+  $keystone_admin_token  = hiera('keystone::admin_token', ''),
+  $zookeeper_client_ip   = hiera('neutron::bind_host', ''),
+  $zookeeper_hostnames   = hiera('controller_node_names', ''),
+  $neutron_api_node_ips  = hiera('neutron_api_node_ips', ''),
+  $bind_address          = hiera('neutron::bind_host', ''),
+  $admin_password        = hiera('admin_password', ''),
+  $zk_on_controller      = hiera('enable_zookeeper_on_controller', ''),
+  $neutron_auth_tenant   = hiera('neutron::server::auth_tenant', ''),
+  $neutron_auth_password = hiera('neutron::server::auth_password', ''),
+  $step                  = hiera('step'),
+) {
+
+  include ::tripleo::profile::base::neutron
+
+  if $step >= 4 {
+    class { '::neutron':
+      service_plugins => []
+    }
+
+    # Run zookeeper in the controller if configured
+    if zk_on_controller {
+      class {'::tripleo::cluster::zookeeper':
+        zookeeper_server_ips => $neutron_api_node_ips,
+        # TODO: create a 'bind' hiera key for zookeeper
+        zookeeper_client_ip  => $zookeeper_client_ip,
+        zookeeper_hostnames  => split($zookeeper_hostnames, ',')
+      }
+    }
+
+    # Run cassandra in the controller if configured
+    if hiera('enable_cassandra_on_controller') {
+      class {'::tripleo::cluster::cassandra':
+        cassandra_servers => $neutron_api_node_ips,
+        cassandra_ip      => $bind_address,
+      }
+    }
+
+    class {'::tripleo::network::midonet::agent':
+      zookeeper_servers => $neutron_api_node_ips,
+      cassandra_seeds   => $neutron_api_node_ips
+    }
+
+    class {'::tripleo::network::midonet::api':
+      zookeeper_servers    => $neutron_api_node_ips,
+      vip                  => $vip,
+      keystone_ip          => $vip,
+      keystone_admin_token => $keystone_admin_token,
+      bind_address         => $bind_address,
+      admin_password       => $admin_password,
+    }
+
+    class {'::neutron::plugins::midonet':
+      midonet_api_ip    => $vip,
+      keystone_tenant   => $neutron_auth_tenant,
+      keystone_password => $neutron_auth_password
+    }
+  }
+}
diff --git a/manifests/profile/base/neutron/ml2.pp b/manifests/profile/base/neutron/ml2.pp
new file mode 100644
index 0000000..47b1b3c
--- /dev/null
+++ b/manifests/profile/base/neutron/ml2.pp
@@ -0,0 +1,57 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron::ml2
+#
+# Neutron ML2 driver profile for tripleo
+#
+# === Parameters
+#
+# [*mechanism_drivers*]
+#   (Optional) The mechanism drivers to use with the Ml2 plugin
+#   Defaults to hiera('neutron::plugins::ml2::mechanism_drivers')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron::ml2 (
+  $mechanism_drivers  = hiera('neutron::plugins::ml2::mechanism_drivers'),
+  $step               = hiera('step'),
+) {
+
+  if $step >= 4 {
+    include ::neutron::plugins::ml2
+    include ::tripleo::profile::base::neutron
+
+    if 'cisco_n1kv' in $mechanism_drivers {
+      include ::tripleo::profile::base::neutron::n1k
+    }
+
+    if 'cisco_ucsm' in $mechanism_drivers {
+      include ::neutron::plugins::ml2::cisco::ucsm
+    }
+
+    if 'cisco_nexus'  in $mechanism_drivers {
+      include ::neutron::plugins::ml2::cisco::nexus
+      include ::neutron::plugins::ml2::cisco::type_nexus_vxlan
+    }
+
+    if 'bsn_ml2' in $mechanism_drivers {
+      include ::neutron::plugins::ml2::bigswitch::restproxy
+      include ::neutron::agents::bigswitch
+    }
+  }
+}
diff --git a/manifests/profile/base/neutron/n1k.pp b/manifests/profile/base/neutron/n1k.pp
new file mode 100644
index 0000000..8c8cfbd
--- /dev/null
+++ b/manifests/profile/base/neutron/n1k.pp
@@ -0,0 +1,54 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron::n1k
+#
+# Neutron N1k Mechanism Driver profile for tripleo
+#
+# === Parameters
+#
+# [*n1kv_source*]
+#   (Optional) The source location for the N1Kv
+#   Defaults to hiera('n1kv_vem_source', undef)
+#
+# [*n1kv_version*]
+#   (Optional) The version of N1Kv to use
+#   Defaults to hiera('n1kv_vem_version', undef)
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron::n1k (
+  $n1kv_source  = hiera('n1kv_vem_source', undef),
+  $n1kv_version = hiera('n1kv_vem_version', undef),
+  $step         = hiera('step'),
+) {
+  include ::neutron::plugins::ml2::cisco::nexus1000v
+  include ::tripleo::profile::base::neutron
+
+  if $step >= 4 {
+    class { '::neutron::agents::n1kv_vem':
+      n1kv_source  => $n1kv_source,
+      n1kv_version => $n1kv_version,
+    }
+
+    class { '::n1k_vsm':
+      n1kv_source       => $n1kv_source,
+      n1kv_version      => $n1kv_version,
+      pacemaker_control => false,
+    }
+  }
+}
diff --git a/manifests/profile/base/neutron/nuage.pp b/manifests/profile/base/neutron/nuage.pp
new file mode 100644
index 0000000..62e6c4f
--- /dev/null
+++ b/manifests/profile/base/neutron/nuage.pp
@@ -0,0 +1,31 @@
+# Copyright 2014 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron:nuage:
+#
+# Nuage Neutron profile for tripleo
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron::nuage (
+  $step = hiera('step'),
+) {
+  include ::tripleo::profile::base::neutron::server
+  if $step >= 4 {
+    include ::neutron::plugins::nuage
+  }
+}
diff --git a/manifests/profile/base/neutron/ovs.pp b/manifests/profile/base/neutron/ovs.pp
new file mode 100644
index 0000000..783952b
--- /dev/null
+++ b/manifests/profile/base/neutron/ovs.pp
@@ -0,0 +1,52 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron::ovs
+#
+# Neutron OVS Agent profile for tripleo
+#
+# === Parameters
+#
+# [*manage_service*]
+#   (Optional) Whether to manage the Neutron OVS Agent service
+#   Defaults to undef
+#
+# [*enabled*]
+#   (Optional) Whether to enable the Neutron OVS Agent service
+#   Defaults to undef
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron::ovs(
+  $manage_service = undef,
+  $enabled        = undef,
+  $step           = hiera('step'),
+) {
+
+  include ::tripleo::profile::base::neutron
+
+  if $step >= 4 {
+    class { '::neutron::agents::ml2::ovs':
+      manage_service => $manage_service,
+      enabled        => $enabled
+    }
+
+    # Optional since manage_service may be false and neutron server may not be colocated.
+    Service<| title == 'neutron-server' |> -> Service<| title == 'neutron-ovs-agent-service' |>
+  }
+
+}
diff --git a/manifests/profile/base/neutron/server.pp b/manifests/profile/base/neutron/server.pp
new file mode 100644
index 0000000..20127ed
--- /dev/null
+++ b/manifests/profile/base/neutron/server.pp
@@ -0,0 +1,60 @@
+# Copyright 2014 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::neutron::server
+#
+# Neutron server profile for tripleo
+#
+# === Parameters
+#
+# [*sync_db*]
+#   (Optional) Whether to run Neutron DB sync operations
+#   Defaults to undef
+#
+# [*manage_service*]
+#   (Optional) Whether to manage the Neutron Server service
+#   Defaults to undef
+#
+# [*enabled*]
+#   (Optional) Whether to enable the Neutron Server service
+#   Defaults to undef
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::neutron::server (
+  $sync_db          = true,
+  $manage_service   = undef,
+  $enabled          = undef,
+  $step             = hiera('step'),
+) {
+
+  include ::tripleo::profile::base::neutron
+
+  if $step >= 3 and $sync_db {
+    include ::neutron::db::mysql
+  }
+
+  if $step >= 4 or ($step >=3 and $sync_db) {
+    include ::neutron::server::notifications
+
+    class { '::neutron::server':
+      sync_db        => $sync_db,
+      manage_service => $manage_service,
+      enabled        => $enabled
+    }
+  }
+}