Add mongodb profiles

Implements: blueprint refactor-puppet-manifests

Co-Authored-By: Carlos Camacho <ccamacho@redhat.com>
Co-Authored-By: Juan Antonio Osorio Robles <jaosorior@redhat.com>
Change-Id: Idb1e78ebec7682fe68ca5902a22cfb6030498091

4 files changed, 217 insertions, 0 deletions

diff --git a/manifests/profile/base/database/mongodb.pp b/manifests/profile/base/database/mongodb.pp
new file mode 100644
index 0000000..4c53c9c
--- /dev/null
+++ b/manifests/profile/base/database/mongodb.pp
@@ -0,0 +1,54 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::database::mongodb
+#
+# Mongodb profile for tripleo
+#
+# === Parameters
+#
+# [*mongodb_replset*]
+#   Mongodb replicaset name
+#
+# [*bootstrap_node*]
+#   (Optional) The hostname of the node responsible for bootstrapping tasks
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::base::database::mongodb (
+  $mongodb_replset,
+  $bootstrap_node       = downcase(hiera('bootstrap_nodeid')),
+  $step                 = hiera('step'),
+) {
+
+  if $step >= 2 {
+
+    include ::mongodb::globals
+    include ::mongodb::client
+    include ::mongodb::server
+
+    include ::tripleo::profile::base::database::mongodbcommon
+
+    if $bootstrap_node == $::hostname {
+      mongodb_replset { $mongodb_replset :
+        members => $tripleo::profile::base::database::mongodbcommon::mongo_node_ips_with_port_nobr,
+      }
+    }
+
+  }
+}
diff --git a/manifests/profile/base/database/mongodbcommon.pp b/manifests/profile/base/database/mongodbcommon.pp
new file mode 100644
index 0000000..6530730
--- /dev/null
+++ b/manifests/profile/base/database/mongodbcommon.pp
@@ -0,0 +1,52 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::database::mongodb
+#
+# Mongodb profile for tripleo
+#
+# === Parameters
+#
+# [*mongodb_node_ips*]
+#   List of The mongodb node ip addresses
+#
+# [*mongodb_ipv6_enabled*]
+#   A boolean value for mongodb server ipv6 is enabled or not
+#   Defaults to false
+#
+class tripleo::profile::base::database::mongodbcommon (
+  $mongodb_node_ips     = hiera('mongo_node_ips'),
+  $mongodb_ipv6_enabled = false,
+) {
+
+  $port = '27017'
+
+  # NOTE(gfidente): the following vars are needed on all nodes so they
+  # need to stay out of pacemaker_master conditional.
+  # The addresses mangling will hopefully go away when we'll be able to
+  # configure the connection string via hostnames, until then, we need to pass
+  # the list of IPv6 addresses *with* port and without the brackets as 'members'
+  # argument for the 'mongodb_replset' resource.
+  if str2bool($mongodb_ipv6_enabled) {
+    $mongo_node_ips_with_port_prefixed = prefix($mongodb_node_ips, '[')
+    $mongo_node_ips_with_port = suffix(
+      $mongo_node_ips_with_port_prefixed, "]:${port}")
+    $mongo_node_ips_with_port_nobr = suffix($mongodb_node_ips, ":${port}")
+  } else {
+    $mongo_node_ips_with_port = suffix($mongodb_node_ips, ":${port}")
+    $mongo_node_ips_with_port_nobr = suffix($mongodb_node_ips, ":${port}")
+  }
+  $mongo_node_string = join($mongo_node_ips_with_port, ',')
+
+}
diff --git a/manifests/profile/pacemaker/database/mongodb.pp b/manifests/profile/pacemaker/database/mongodb.pp
new file mode 100644
index 0000000..15c84d7
--- /dev/null
+++ b/manifests/profile/pacemaker/database/mongodb.pp
@@ -0,0 +1,74 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::database::mongodb
+#
+# Mongodb Pacemaker HA profile for tripleo
+#
+# === Parameters
+#
+# [*mongodb_replset*]
+#   Mongodb replicaset name
+#
+# [*bootstrap_node*]
+#   (Optional) The hostname of the node responsible for bootstrapping tasks
+#   Defaults to hiera('bootstrap_nodeid')
+#
+# [*step*]
+#   (Optional) The current step in deployment. See tripleo-heat-templates
+#   for more details.
+#   Defaults to hiera('step')
+#
+class tripleo::profile::pacemaker::database::mongodb (
+  $mongodb_replset,
+  $bootstrap_node       = hiera('bootstrap_nodeid'),
+  $step                 = hiera('step'),
+) {
+
+  if $step >= 1 {
+    include ::mongodb::globals
+    include ::mongodb::client
+    include ::mongodb::server
+  }
+
+  if $step >= 2 {
+
+    include ::tripleo::profile::base::database::mongodbcommon
+
+    if $::hostname == downcase($bootstrap_node) {
+      $pacemaker_master = true
+    } else {
+      $pacemaker_master = false
+    }
+
+    if $pacemaker_master {
+      pacemaker::resource::service { $::mongodb::params::service_name :
+        op_params    => 'start timeout=370s stop timeout=200s',
+        clone_params => true,
+        require      => Class['::mongodb::server'],
+      }
+      # NOTE (spredzy) : The replset can only be run
+      # once all the nodes have joined the cluster.
+      tripleo::profile::pacemaker::database::mongodbvalidator {
+        $tripleo::profile::base::database::mongodbcommon::mongodb_node_ips :
+        port    => $tripleo::profile::base::database::mongodbcommon::port,
+        require => Pacemaker::Resource::Service[$::mongodb::params::service_name],
+        before  => Mongodb_replset[$mongodb_replset],
+      }
+      mongodb_replset { $mongodb_replset :
+        members => $tripleo::profile::base::database::mongodbcommon::mongo_node_ips_with_port_nobr,
+      }
+    }
+  }
+}
diff --git a/manifests/profile/pacemaker/database/mongodbvalidator.pp b/manifests/profile/pacemaker/database/mongodbvalidator.pp
new file mode 100644
index 0000000..95d3bd7
--- /dev/null
+++ b/manifests/profile/pacemaker/database/mongodbvalidator.pp
@@ -0,0 +1,37 @@
+# Copyright 2016 Red Hat, Inc.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#      http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::pacemaker::database::mongodb::conn_validator
+#
+# Connection validator for a node that serves MongoDB. This is done to be able
+# to iterate through the different servers in a more seamless way.
+#
+# === Parameters
+#
+# [*title*]
+#   the title or namevar of the resource will be used as the server of the
+#   actual mongodb_conn_validator.
+#
+# [*port*]
+#   The port in which the MongoDB server is listening on.
+#
+define tripleo::profile::pacemaker::database::mongodbvalidator(
+  $port,
+) {
+  mongodb_conn_validator { "${title}_conn_validator" :
+    server  => $title,
+    port    => $port,
+    timeout => '600',
+  }
+}