From 8dcfe1a692815ee3a34dca32fd427471dfd0046a Mon Sep 17 00:00:00 2001
From: blsaws <bs3131@att.com>
Date: Mon, 16 May 2016 07:40:31 -0700
Subject: Refactor installer code folders.

JIRA: COPPER-2
Add initial centos7 bash scripts in development.

Change-Id: I112aa43c231dac035f0d1bc2ae416fabf6b8b650
Signed-off-by: blsaws <bs3131@att.com>
---
 .../congress/install/puppet/manifests/db/mysql.pp  | 69 ++++++++++++++++++++++
 .../install/puppet/manifests/db/postgresql.pp      | 55 +++++++++++++++++
 .../congress/install/puppet/manifests/db/sync.pp   | 14 +++++
 3 files changed, 138 insertions(+)
 create mode 100644 components/congress/install/puppet/manifests/db/mysql.pp
 create mode 100644 components/congress/install/puppet/manifests/db/postgresql.pp
 create mode 100644 components/congress/install/puppet/manifests/db/sync.pp

(limited to 'components/congress/install/puppet/manifests/db')

diff --git a/components/congress/install/puppet/manifests/db/mysql.pp b/components/congress/install/puppet/manifests/db/mysql.pp
new file mode 100644
index 0000000..456b812
--- /dev/null
+++ b/components/congress/install/puppet/manifests/db/mysql.pp
@@ -0,0 +1,69 @@
+# The congress::db::mysql class implements mysql backend for congress
+#
+# This class can be used to create tables, users and grant
+# privelege for a mysql congress database.
+#
+# == parameters
+#
+# [*password*]
+#   (Mandatory) Password to connect to the database.
+#   Defaults to 'false'.
+#
+# [*dbname*]
+#   (Optional) Name of the database.
+#   Defaults to 'congress'.
+#
+# [*user*]
+#   (Optional) User to connect to the database.
+#   Defaults to 'congress'.
+#
+# [*host*]
+#   (Optional) The default source host user is allowed to connect from.
+#   Defaults to '127.0.0.1'
+#
+# [*allowed_hosts*]
+#   (Optional) Other hosts the user is allowed to connect from.
+#   Defaults to 'undef'.
+#
+# [*charset*]
+#   (Optional) The database charset.
+#   Defaults to 'utf8'
+#
+# [*collate*]
+#   (Optional) The database collate.
+#   Only used with mysql modules >= 2.2.
+#   Defaults to 'utf8_general_ci'
+#
+# == Dependencies
+#   Class['mysql::server']
+#
+# == Examples
+#
+# == Authors
+#
+# == Copyright
+#
+class congress::db::mysql(
+  $password,
+  $dbname        = 'congress',
+  $user          = 'congress',
+  $host          = '127.0.0.1',
+  $charset       = 'utf8',
+  $collate       = 'utf8_general_ci',
+  $allowed_hosts = undef
+) {
+
+  validate_string($password)
+
+  ::openstacklib::db::mysql { 'congress':
+    user          => $user,
+    password_hash => mysql_password($password),
+    dbname        => $dbname,
+    host          => $host,
+    charset       => $charset,
+    collate       => $collate,
+    allowed_hosts => $allowed_hosts,
+  }
+
+  ::Openstacklib::Db::Mysql['congress'] ~> Exec<| title == 'congress-manage db_sync' |>
+}
diff --git a/components/congress/install/puppet/manifests/db/postgresql.pp b/components/congress/install/puppet/manifests/db/postgresql.pp
new file mode 100644
index 0000000..4766eca
--- /dev/null
+++ b/components/congress/install/puppet/manifests/db/postgresql.pp
@@ -0,0 +1,55 @@
+# == Class: congress::db::postgresql
+#
+# Class that configures postgresql for congress
+# Requires the Puppetlabs postgresql module.
+#
+# === Parameters
+#
+# [*password*]
+#   (Required) Password to connect to the database.
+#
+# [*dbname*]
+#   (Optional) Name of the database.
+#   Defaults to 'congress'.
+#
+# [*user*]
+#   (Optional) User to connect to the database.
+#   Defaults to 'congress'.
+#
+#  [*encoding*]
+#    (Optional) The charset to use for the database.
+#    Default to undef.
+#
+#  [*privileges*]
+#    (Optional) Privileges given to the database user.
+#    Default to 'ALL'
+#
+# == Dependencies
+#
+# == Examples
+#
+# == Authors
+#
+# == Copyright
+#
+class congress::db::postgresql(
+  $password,
+  $dbname     = 'congress',
+  $user       = 'congress',
+  $encoding   = undef,
+  $privileges = 'ALL',
+) {
+
+  Class['congress::db::postgresql'] -> Service<| title == 'congress' |>
+
+  ::openstacklib::db::postgresql { 'congress':
+    password_hash => postgresql_password($user, $password),
+    dbname        => $dbname,
+    user          => $user,
+    encoding      => $encoding,
+    privileges    => $privileges,
+  }
+
+  ::Openstacklib::Db::Postgresql['congress'] ~> Exec<| title == 'congress-manage db_sync' |>
+
+}
diff --git a/components/congress/install/puppet/manifests/db/sync.pp b/components/congress/install/puppet/manifests/db/sync.pp
new file mode 100644
index 0000000..bb07f7e
--- /dev/null
+++ b/components/congress/install/puppet/manifests/db/sync.pp
@@ -0,0 +1,14 @@
+#
+# Class to execute "congress-manage db_sync
+#
+class congress::db::sync {
+  exec { 'congress-manage db_sync':
+    path        => '/usr/bin',
+    user        => 'congress',
+    refreshonly => true,
+    subscribe   => [Package['congress'], congress_config['database/connection']],
+    require     => User['congress'],
+  }
+
+  Exec['congress-manage db_sync'] ~> Service<| title == 'congress' |>
+}
-- 
cgit 1.2.3-korg