aboutsummaryrefslogtreecommitdiffstats
path: root/manifests/certmonger/rabbitmq.pp
blob: bcc328acfcbe228c56819d14aa4792fe289cb4e9 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
# Copyright 2016 Red Hat, Inc.
#
# Licensed under the Apache License, Version 2.0 (the "License"); you may
# not use this file except in compliance with the License. You may obtain
# a copy of the License at
#
#      http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
# License for the specific language governing permissions and limitations
# under the License.
#
# == Class: tripleo::certmonger::rabbitmq
#
# Request a certificate for RabbitMQ and do the necessary setup.
#
# === Parameters
#
# [*hostname*]
#   The hostname of the node. this will be set in the CN of the certificate.
#
# [*service_certificate*]
#   The path to the certificate that will be used for TLS in this service.
#
# [*service_key*]
#   The path to the key that will be used for TLS in this service.
#
# [*certmonger_ca*]
#   (Optional) The CA that certmonger will use to generate the certificates.
#   Defaults to hiera('certmonger_ca', 'local').
#
# [*file_owner*]
#   (Optional) The user which the certificate and key files belong to.
#   Defaults to 'root'
#
# [*principal*]
#   (Optional) The service principal that is set for the service in kerberos.
#   Defaults to undef
#
class tripleo::certmonger::rabbitmq (
  $hostname,
  $service_certificate,
  $service_key,
  $certmonger_ca = hiera('certmonger_ca', 'local'),
  $principal     = undef,
) {
  include ::certmonger
  include ::rabbitmq::params

  $postsave_cmd  = "systemctl restart ${::rabbitmq::params::service_name}"
  certmonger_certificate { 'rabbitmq' :
    ensure       => 'present',
    certfile     => $service_certificate,
    keyfile      => $service_key,
    hostname     => $hostname,
    dnsname      => $hostname,
    principal    => $principal,
    postsave_cmd => $postsave_cmd,
    ca           => $certmonger_ca,
    wait         => true,
    require      => Class['::certmonger'],
  }

  file { $service_certificate :
    owner   => $::rabbitmq::params::rabbitmq_user,
    group   => $::rabbitmq::params::rabbitmq_group,
    require => Certmonger_certificate['rabbitmq'],
  }
  file { $service_key :
    owner   => $::rabbitmq::params::rabbitmq_user,
    group   => $::rabbitmq::params::rabbitmq_group,
    require => Certmonger_certificate['rabbitmq'],
  }

  File[$service_certificate] ~> Service<| title == $::rabbitmq::params::service_name |>
  File[$service_key] ~> Service<| title == $::rabbitmq::params::service_name |>
}