From 149f04e9cf19c8266a118be24a423b1ccd1b4064 Mon Sep 17 00:00:00 2001
From: Steven Hardy <shardy@redhat.com>
Date: Thu, 2 Mar 2017 11:48:09 +0000
Subject: Add docker profile

This configures the docker service on the host, as an alternative
to the firstboot script in docker/firstboot/setup_docker_host.sh

Doing this via puppet will enable easier integration with e.g
the multinode jobs where no firstboot scripts run, and also
enables a better error path in the event the service fails to start

Co-Authored-By: Alex Schultz <aschultz@redhat.com>
Change-Id: Id8add1e8a0ecaedb7d8a7dc9ba3747c1ac3b8eea
---
 manifests/profile/base/docker.pp | 68 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 manifests/profile/base/docker.pp

(limited to 'manifests/profile')

diff --git a/manifests/profile/base/docker.pp b/manifests/profile/base/docker.pp
new file mode 100644
index 0000000..5e18a85
--- /dev/null
+++ b/manifests/profile/base/docker.pp
@@ -0,0 +1,68 @@
+# Copyright 2017 Red Hat, Inc.
+# All Rights Reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License"); you may
+# not use this file except in compliance with the License. You may obtain
+# a copy of the License at
+#
+#     http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
+# WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
+# License for the specific language governing permissions and limitations
+# under the License.
+#
+# == Class: tripleo::profile::base::docker
+#
+# docker profile for tripleo
+#
+# === Parameters
+#
+# [*docker_namespace*]
+#   The namespace to be used when setting INSECURE_REGISTRY
+#   this will be split on "/" to derive the docker registry
+#   (defaults to undef)
+#
+# [*insecure_registry*]
+#   Set docker_namespace to INSECURE_REGISTRY, used when a local registry
+#   is enabled (defaults to false)
+#
+# [*step*]
+#   step defaults to hiera('step')
+#
+class tripleo::profile::base::docker (
+  $docker_namespace = undef,
+  $insecure_registry = false,
+  $step = hiera('step'),
+) {
+  if $step >= 1 {
+    package {'docker':
+      ensure => installed,
+    }
+
+    service { 'docker':
+      ensure  => 'running',
+      enable  => true,
+      require => Package['docker'],
+    }
+
+    if $insecure_registry {
+      if $docker_namespace == undef {
+        fail('You must provide a $docker_namespace in order to configure insecure registry')
+      }
+      $namespace = strip($docker_namespace.split('/')[0])
+      $changes = [ "set INSECURE_REGISTRY '\"--insecure-registry ${namespace}\"'", ]
+    } else {
+      $changes = [ 'rm INSECURE_REGISTRY', ]
+    }
+
+    augeas { 'docker-sysconfig':
+      lens      => 'Shellvars.lns',
+      incl      => '/etc/sysconfig/docker',
+      changes   => $changes,
+      subscribe => Package['docker'],
+      notify    => Service['docker'],
+    }
+  }
+}
-- 
cgit 1.2.3-korg