From eec3bba44b5a7e09dba4d427bd0d3d71a4956a7a Mon Sep 17 00:00:00 2001
From: karthik s <ksundara@redhat.com>
Date: Fri, 26 Aug 2016 21:48:04 +0530
Subject: Configure the numvfs for SRIOV interfaces

This patch shall create VFs via the PCI SYS interface.
Default value : $::os_service_default
Sample Format : ['eth0:4','eth2:128']
For values as in sample format, the sriov_numvfs config files
for eth0 and eth2 will have the values 4 and 128 respectively
The SR-IOV numvfs configuration shall be persisted in /sbin/ifup-local
so that, during the bootup of the compute nodes, the numvfs
configuration will be restored.

Change-Id: I7450b904475bdf46498d9af633416b3eba12f761
Implements: blueprint tripleo-sriov
Signed-off-by: karthik s <ksundara@redhat.com>
---
 manifests/host/sriov.pp                    | 27 +++++++++++++++
 manifests/host/sriov/numvfs_persistence.pp | 55 ++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)
 create mode 100644 manifests/host/sriov.pp
 create mode 100644 manifests/host/sriov/numvfs_persistence.pp

(limited to 'manifests/host')

diff --git a/manifests/host/sriov.pp b/manifests/host/sriov.pp
new file mode 100644
index 0000000..a30db42
--- /dev/null
+++ b/manifests/host/sriov.pp
@@ -0,0 +1,27 @@
+# == Class: tripleo::host::sriov
+#
+# Configures host configuration for the SR-IOV interfaces
+#
+# === Parameters
+#
+# [*number_of_vfs*]
+#   (optional) List of <physical_network>:<number_of_vfs> specifying the number
+#   VFs to be exposed per physical interface.
+#   For example, to configure two interface with number of VFs, specify
+#   it as ['eth1:4','eth2:10']
+#   Defaults to []
+#
+class tripleo::host::sriov (
+  $number_of_vfs = [],
+) {
+
+  if !empty($number_of_vfs) {
+    sriov_vf_config { $number_of_vfs: ensure => present }
+
+    # the numvfs configuration needs to be persisted for every boot
+    tripleo::host::sriov::numvfs_persistence {'persistent_numvfs':
+      vf_defs        => $number_of_vfs,
+      content_string => "#!/bin/bash\n"
+    }
+  }
+}
diff --git a/manifests/host/sriov/numvfs_persistence.pp b/manifests/host/sriov/numvfs_persistence.pp
new file mode 100644
index 0000000..1ee402c
--- /dev/null
+++ b/manifests/host/sriov/numvfs_persistence.pp
@@ -0,0 +1,55 @@
+#
+# tripleo::host::sriov::numvfs_persistence used by tripleo::host::sriov
+#
+# === Parameters:
+#
+# [*vf_defs*]
+#   (required) Array of of <physical_interface>:<numvfs>.
+#   Example: ['eth1:10','eth2:8']
+#
+# [*content_string*]
+#   (required) String which shall be written to the script file.
+#
+define tripleo::host::sriov::numvfs_persistence(
+  $vf_defs,
+  $content_string
+){
+  # Since reduce isn't available, we use recursion to iterate each entries of
+  # "physical_interface:vfs" and accumulate the content that needs to be
+  # written to the script file.
+  include ::stdlib
+
+  if empty($vf_defs) {
+    file { '/etc/sysconfig/allocate_vfs':
+      ensure  => file,
+      content => $content_string,
+      group   => 'root',
+      mode    => '0755',
+      owner   => 'root',
+    }
+
+    file { '/sbin/ifup-local':
+      group   => 'root',
+      mode    => '0755',
+      owner   => 'root',
+      content => '#!/bin/bash',
+      replace => false
+    }
+
+    file_line { 'call_ifup-local':
+      path    => '/sbin/ifup-local',
+      line    => '/etc/sysconfig/allocate_vfs $1',
+      require => File['/sbin/ifup-local'],
+    }
+  } else {
+    $vfspec = split($vf_defs[0], ':')
+    $interface = $vfspec[0]
+    $count = $vfspec[1]
+    $vfdef_str = "${content_string}[ \"${interface}\" == \"\$1\" ] && echo ${count} > /sys/class/net/${interface}/device/sriov_numvfs\n"
+    tripleo::host::sriov::numvfs_persistence{"mapped ${interface}":
+      vf_defs        => delete_at($vf_defs, 0),
+      content_string => $vfdef_str
+    }
+  }
+}
+
-- 
cgit 1.2.3-korg